add flake.nix and fix issues with build system variable expansion

.gitignore

@@ -2,3 +2,4 @@ bin
 build
 *~
 .vs
+result

flake.nix

@@ -0,0 +1,56 @@
+{
+    description = "Touhou Toolkit";
+
+    inputs = {
+        nixpkgs.url = "https://channels.nixos.org/nixpkgs-unstable/nixexprs.tar.zst";
+    };
+
+    outputs = inputs: {
+        packages = builtins.mapAttrs (system: pkgs: let
+            inherit (pkgs) lib stdenv fetchFromGitHub;
+            thtypes = fetchFromGitHub {
+                owner = "thpatch";
+                repo = "thtypes";
+                rev = "29ed7d6e1db555ad15fd29edcc0763754ad5b764";
+                hash = "sha256-j3lrToLuS7SbzzdL3/8uB0nL1z04GtmfmKIC/v37jwI=";
+            };
+        in {
+            thtk = stdenv.mkDerivation {
+                pname = "thtk";
+                version = "12";
+
+                src = inputs.self;
+
+                env.NIX_CFLAGS_COMPILE = "-I${thtypes}";
+
+                nativeBuildInputs = with pkgs; [
+                    cmake
+                    pkg-config
+                    validatePkgConfig
+                    flex
+                    bison
+                ];
+
+                buildInputs = with pkgs; [
+                    zlib
+                    libpng
+                ];
+
+                cmakeFlags = [
+                    (lib.cmakeBool "WITH_LIBPNG_SOURCE" false)
+                ];
+
+                meta = {
+                    description = "Touhou Toolkit";
+                    homepage = "https://github.com/thpatch/thtk";
+                    changelog = "https://github.com/thpatch/thtk/releases";
+                    license = lib.licenses.bsd2;
+                    pkgConfigModules = [ "thtk" ];
+                    platforms = with lib.platforms; linux ++ windows;
+                };
+            };
+
+            default = inputs.self.packages.${system}.thtk;
+        }) inputs.nixpkgs.legacyPackages;
+    };
+}

thtk/CMakeLists.txt

@@ -27,7 +27,7 @@ set_target_properties(thtk PROPERTIES
 
 find_package(PkgConfig)
 if (PKG_CONFIG_FOUND)
-  configure_file(thtk.pc.in ${CMAKE_CURRENT_BINARY_DIR}/thtk.pc)
+  configure_file(thtk.pc.in ${CMAKE_CURRENT_BINARY_DIR}/thtk.pc @ONLY)
   install(FILES ${CMAKE_CURRENT_BINARY_DIR}/thtk.pc
     DESTINATION ${CMAKE_INSTALL_LIBDIR}/pkgconfig)
 endif()

thtk/thtk.pc.in

@@ -1,7 +1,7 @@
 prefix = @CMAKE_INSTALL_PREFIX@
 exec_prefix = ${prefix}
-includedir = ${prefix}/@CMAKE_INSTALL_INCLUDEDIR@
-libdir = ${exec_prefix}/@CMAKE_INSTALL_LIBDIR@
+includedir = @CMAKE_INSTALL_FULL_INCLUDEDIR@
+libdir = @CMAKE_INSTALL_FULL_LIBDIR@
 
 Name: @PROJECT_NAME@
 Description: Touhou Toolkit shared library