Don't leak curses CPPFLAGS into the whole-interpreter build

The wide-character probe ran inside a nested WITH_SAVE_ENV, whose single
CPPFLAGS save slot is not reentrant, so the outer restore leaked
$CURSES_CFLAGS and $PANEL_CFLAGS (-D_XOPEN_SOURCE=600) into
CONFIGURE_CPPFLAGS and thus into every translation unit, producing a
'_XOPEN_SOURCE' redefined warning against pyconfig.h on every file.

Save and restore CPPFLAGS with a dedicated variable around the probe,
as on the main branch.

Author: serhiy-storchaka

configure

@@ -7199,21 +7199,23 @@ dnl the system curses of NetBSD, or an ncurses built with --enable-widec that
 dnl keeps the plain name (pkgsrc, macOS).  Probe for the wide API and, if
 dnl present, build the module wide by defining HAVE_NCURSESW.
 AS_VAR_IF([have_curses], [no], [], [
-  WITH_SAVE_ENV([
-    dnl Use the adjusted CURSES_CFLAGS (e.g. macOS's -D_XOPEN_SOURCE_EXTENDED)
-    dnl so the wide-character declarations are visible to the probe.
-    AS_VAR_APPEND([CPPFLAGS], [" $CURSES_CFLAGS"])
-    AC_CACHE_CHECK([whether curses supports wide characters],
-      [ac_cv_curses_wide],
-      [AC_LINK_IFELSE(
-        [AC_LANG_PROGRAM([_CURSES_INCLUDES], [[
-          cchar_t wcval;
-          setcchar(&wcval, L"x", A_NORMAL, 0, NULL);
-          add_wch(&wcval);
-        ]])],
-        [ac_cv_curses_wide=yes],
-        [ac_cv_curses_wide=no])])
-  ])
+  dnl Use the adjusted CURSES_CFLAGS (e.g. macOS's -D_XOPEN_SOURCE_EXTENDED)
+  dnl so the wide-character declarations are visible to the probe.  This runs
+  dnl inside an outer WITH_SAVE_ENV, whose single CPPFLAGS save slot is not
+  dnl reentrant, so save and restore CPPFLAGS with a dedicated variable here.
+  save_curses_cppflags=$CPPFLAGS
+  AS_VAR_APPEND([CPPFLAGS], [" $CURSES_CFLAGS"])
+  AC_CACHE_CHECK([whether curses supports wide characters],
+    [ac_cv_curses_wide],
+    [AC_LINK_IFELSE(
+      [AC_LANG_PROGRAM([_CURSES_INCLUDES], [[
+        cchar_t wcval;
+        setcchar(&wcval, L"x", A_NORMAL, 0, NULL);
+        add_wch(&wcval);
+      ]])],
+      [ac_cv_curses_wide=yes],
+      [ac_cv_curses_wide=no])])
+  CPPFLAGS=$save_curses_cppflags
   dnl HAVE_NCURSESW marks the wide (cchar_t) curses API; its template comes
   dnl from the ncursesw pkg-config check above, so no description here.
   AS_VAR_IF([ac_cv_curses_wide], [yes], [AC_DEFINE([HAVE_NCURSESW], [1])])