Migrate to io.github.gradle-nexus.publish-plugin

Author: pengrad

build.gradle

@@ -1,5 +1,23 @@
+plugins {
+    id "io.github.gradle-nexus.publish-plugin" version "1.3.0"
+    id "maven-publish"
+    id "signing"
+}
+
+group = GROUP
+version = VERSION_NAME
+
+nexusPublishing {
+    repositories {
+        sonatype {
+            username = project.findProperty("SONATYPE_NEXUS_USERNAME")
+            password = project.findProperty("SONATYPE_NEXUS_PASSWORD")
+        }
+    }
+}
+
 subprojects {
     repositories {
-        jcenter()
+        mavenCentral()
     }
 }

gradle/gradle-publish-plugin.gradle

@@ -0,0 +1,56 @@
+java {
+    withJavadocJar()
+    withSourcesJar()
+}
+
+publishing {
+    publications {
+        maven(MavenPublication) {
+            from(components.java)
+
+            pom {
+                groupId = GROUP
+                artifactId = POM_ARTIFACT_ID
+                version = VERSION_NAME
+
+                name = POM_NAME
+                description = POM_DESCRIPTION
+                url = POM_URL
+                licenses {
+                    license {
+                        name = POM_LICENCE_NAME
+                        url = POM_LICENCE_URL
+                        distribution = POM_LICENCE_DIST
+                    }
+                }
+                developers {
+                    developer {
+                        id = POM_DEVELOPER_ID
+                        name = POM_DEVELOPER_NAME
+                    }
+                }
+                scm {
+                    url = POM_SCM_URL
+                    connection = POM_SCM_CONNECTION
+                    developerConnection = POM_SCM_DEV_CONNECTION
+                }
+            }
+        }
+    }
+    repositories {
+        maven {
+            url = layout.buildDirectory.dir('staging-deploy')
+        }
+    }
+}
+
+signing {
+    sign publishing.publications.maven
+}
+
+def generateMavenPom = tasks.register("generateMavenPom", GenerateMavenPom) {
+    destination = file("../pom.xml")
+    pom = publishing.publications.maven.pom
+}
+
+tasks.compileJava.dependsOn generateMavenPom

library/build.gradle

@@ -1,17 +1,19 @@
-apply plugin: 'java'
+plugins {
+    id "java-library"
+}
 apply plugin: 'jacoco'
 
 sourceCompatibility = 1.8
 targetCompatibility = 1.8
 
 dependencies {
-    compile 'com.google.code.gson:gson:2.10.1'
-    compile 'com.squareup.okhttp3:okhttp:4.12.0'
-    compile 'com.squareup.okhttp3:logging-interceptor:4.12.0'
+    api 'com.google.code.gson:gson:2.10.1'
+    api 'com.squareup.okhttp3:okhttp:4.12.0'
+    api 'com.squareup.okhttp3:logging-interceptor:4.12.0'
 
-    testCompile 'junit:junit:4.13.1'
-    testCompile 'nl.jqno.equalsverifier:equalsverifier:3.1.13'
-    testCompile 'org.reflections:reflections:0.9.12'
+    testImplementation 'junit:junit:4.13.1'
+    testImplementation 'nl.jqno.equalsverifier:equalsverifier:3.1.13'
+    testImplementation 'org.reflections:reflections:0.9.12'
 }
 
 jar {
@@ -47,7 +49,6 @@ tasks.withType(Test).configureEach {
     }
 }
 
-
 tasks.register('prTest', Test) {
     // TODO move "functional" tests into specific dir and exclude it
     exclude '**/Base64Test.class'
@@ -57,10 +58,4 @@ tasks.register('prTest', Test) {
     exclude '**/UpdatesListenerTest.class'
 }
 
-task fatJar(type: Jar) {
-    baseName = rootProject.name + '-full'
-    from { configurations.compile.collect { it.isDirectory() ? it : zipTree(it) } }
-    with jar
-}
-
-apply from: rootProject.file('gradle/gradle-mvn-push.gradle')
+apply from: rootProject.file('gradle/gradle-publish-plugin.gradle')

pom.xml

@@ -1,6 +1,11 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <project xsi:schemaLocation="http://maven.apache.org/POM/4.0.0 http://maven.apache.org/xsd/maven-4.0.0.xsd" xmlns="http://maven.apache.org/POM/4.0.0"
     xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">
+  <!-- This module was also published with a richer model, Gradle metadata,  -->
+  <!-- which should be used instead. Do not delete the following line which  -->
+  <!-- is to indicate to Gradle or any Gradle module metadata file consumer  -->
+  <!-- that they should prefer consuming it instead. -->
+  <!-- do_not_remove: published-with-gradle-metadata -->
   <modelVersion>4.0.0</modelVersion>
   <groupId>com.github.pengrad</groupId>
   <artifactId>java-telegram-bot-api</artifactId>
@@ -45,23 +50,5 @@
       <version>4.12.0</version>
       <scope>compile</scope>
     </dependency>
-    <dependency>
-      <groupId>junit</groupId>
-      <artifactId>junit</artifactId>
-      <version>4.13.1</version>
-      <scope>test</scope>
-    </dependency>
-    <dependency>
-      <groupId>nl.jqno.equalsverifier</groupId>
-      <artifactId>equalsverifier</artifactId>
-      <version>3.1.13</version>
-      <scope>test</scope>
-    </dependency>
-    <dependency>
-      <groupId>org.reflections</groupId>
-      <artifactId>reflections</artifactId>
-      <version>0.9.12</version>
-      <scope>test</scope>
-    </dependency>
   </dependencies>
 </project>

sample/build.gradle

@@ -8,13 +8,12 @@ compileJava {
 }
 
 repositories {
-    jcenter()
+    mavenCentral()
 }
 
 dependencies {
-    compile project(':library')
-
-    compile 'com.sparkjava:spark-core:2.2'
-    compile 'org.jsoup:jsoup:1.8.3'
-    compile 'io.reactivex:rxjava:1.0.16'
+    implementation project(':library')
+    implementation 'com.sparkjava:spark-core:2.2'
+    implementation 'org.jsoup:jsoup:1.8.3'
+    implementation 'io.reactivex:rxjava:1.0.16'
 }