opm list -remote

Author: asosnoviy

src/Классы/ДиспетчерКомандПриложения.os

@@ -82,6 +82,7 @@
 Процедура ДобавитьКомандуList(Знач Парсер)
 	Команда = Парсер.ОписаниеКоманды("list", "Вывести список пакетов");
 	Парсер.ДобавитьПараметрФлагКоманды(Команда, "-q", """Тихий"" режим вывода без лишних сообщений.");
+	Парсер.ДобавитьПараметрФлагКоманды(Команда, "-remote", "Вывести список пакетов в хабе");
 	Парсер.ДобавитьКоманду(Команда);
 КонецПроцедуры
 
@@ -213,15 +214,23 @@
 
 	ТихийРежим = ЗначенияПараметров["-q"];
 
-	ПутьККаталогуПакетов = ПолучитьЗначениеСистемнойНастройки("lib.system");
+	Если ЗначенияПараметров["-remote"] Тогда
+		ТекстСообщения  = СтрШаблон("Пакеты в хабе :");		
+		КэшПакетовВХабе = Новый КэшПакетовХаба();	
+		УстановленныеПакеты =  КэшПакетовВХабе.ПолучитьПакетыХаба();	
+	Иначе	
 
+		ПутьККаталогуПакетов = ПолучитьЗначениеСистемнойНастройки("lib.system");
+		ТекстСообщения = СтрШаблон("Пакеты в системном каталоге библиотек <%1>:", ПутьККаталогуПакетов);		
+	
+		КэшУстановленныхПакетов = Новый КэшУстановленныхПакетов();
+		УстановленныеПакеты = КэшУстановленныхПакетов.ПолучитьУстановленныеПакеты();
+	КонецЕсли;
+
 	Если НЕ ТихийРежим Тогда
-		ТекстСообщения = СтрШаблон("Пакеты в системном каталоге библиотек <%1>:", ПутьККаталогуПакетов);
-		Сообщить(ТекстСообщения);
+			Сообщить(ТекстСообщения);
 	КонецЕсли;
 
-	КэшУстановленныхПакетов = Новый КэшУстановленныхПакетов();
-	УстановленныеПакеты = КэшУстановленныхПакетов.ПолучитьУстановленныеПакеты();
 	Для Каждого УстановленныйПакет Из УстановленныеПакеты Цикл
 		Сообщить(УстановленныйПакет.Ключ);
 	КонецЦикла;

src/Классы/КэшПакетовХаба.os

@@ -0,0 +1,64 @@
+
+#Использовать logos
+
+Перем Лог;
+
+Перем ПакетыХаба;
+
+Процедура Обновить() Экспорт
+
+	УстановкаПакета = Новый Установкапакета();
+	Сервер =  Константы.СерверУдаленногоХранилища;
+	Соединение = УстановкаПакета.ИнициализироватьСоединение(Сервер);
+	Ресурс = Константы.ПутьВХранилище + "list.txt";
+	Запрос = Новый HTTPЗапрос(Ресурс);
+	Ответ  = Соединение.Получить(Запрос);
+
+	Если НЕ Ответ.КодСостояния = 200 Тогда
+		ТекстИсключения = СтрШаблон("Ошибка подключения к хабу <%1>", Ответ.КодСостояния);
+		Ответ.Закрыть();
+		ВызватьИсключение ТекстИсключения;
+	КонецЕсли;
+	
+	HTMLхаба = Ответ.ПолучитьТелоКакСтроку();
+	ВремФайл = ОбъединитьПути(КаталогВременныхФайлов(), "list.txt");
+	Ответ.ПолучитьТелоКакДвоичныеДанные().Записать(ВремФайл);
+	Ответ.Закрыть();
+
+	ЧтениеТекста = Новый ЧтениеТекста();
+	ЧтениеТекста.Открыть(ВремФайл);
+	ПакетыХаба = Новый Соответствие;
+
+	СтрокаТекста = ЧтениеТекста.ПрочитатьСтроку();
+	Пока СтрокаТекста <> Неопределено Цикл
+		ПакетыХаба.Вставить(СтрокаТекста, Истина);
+		СтрокаТекста = ЧтениеТекста.ПрочитатьСтроку();
+	КонецЦикла;		
+
+	ЧтениеТекста.Закрыть();
+	УдалитьФайлы(ВремФайл);
+	
+КонецПроцедуры
+
+Функция ЭтоПакетХаба(Знач ИмяПакета) Экспорт
+
+	Возврат ПакетыХаба[ИмяПакета] = Истина;
+
+КонецФункции
+
+Функция ПолучитьПакетыХаба() Экспорт
+
+	Возврат ПакетыХаба;
+
+КонецФункции	
+
+Процедура Инициализация()
+
+	Лог = Логирование.ПолучитьЛог("oscript.app.opm");
+	//Лог.УстановитьУровень(УровниЛога.Отладка);
+	
+	Обновить();
+	
+КонецПроцедуры
+
+Инициализация();

src/Классы/УстановкаПакета.os

@@ -173,10 +173,6 @@
 	Возврат Новый КэшУстановленныхПакетов();
 КонецФункции
 
-Функция СерверУдаленногоХранилища()
-	Возврат "http://hub.oscript.io";
-КонецФункции
-
 Процедура СкачатьИУстановитьПакетПоОписанию(Знач ОписаниеПакета)
 	// TODO: Нужно скачивание конкретной версии по маркеру
 	СкачатьИУстановитьПакет(ОписаниеПакета.ИмяПакета, Неопределено);
@@ -190,20 +186,10 @@
 		ФайлПакета = ИмяПакета + ".ospx";
 	КонецЕсли;
 
-	Сервер = СерверУдаленногоХранилища();
-	Ресурс = "/download/" + ИмяПакета + "/" + ФайлПакета;
+	Сервер = Константы.СерверУдаленногоХранилища;
+	Ресурс = Константы.ПутьВХранилище + ИмяПакета + "/" + ФайлПакета;
+	Соединение = ИнициализироватьСоединение(Сервер);
 
-	НастройкиПрокси = НастройкиПриложения.Получить().Прокси;
-	Если НастройкиПрокси.ИспользоватьПрокси = Истина Тогда
-		Прокси = Новый ИнтернетПрокси(НастройкиПрокси.ПроксиПоУмолчанию);
- 		Если НастройкиПрокси.ПроксиПоУмолчанию = Ложь Тогда
-			Прокси.Установить("http",НастройкиПрокси.Сервер,НастройкиПрокси.Порт,НастройкиПрокси.Пользователь,НастройкиПрокси.Пароль,НастройкиПрокси.ИспользоватьАутентификациюОС);
- 		КонецЕсли;	
-		Соединение = Новый HTTPСоединение(Сервер,,,,Прокси);
-	Иначе
-		Соединение = Новый HTTPСоединение(Сервер);
-	КонецЕсли;
-	
 	Запрос = Новый HTTPЗапрос(Ресурс);
 	Лог.Информация("Скачиваю файл: " + ФайлПакета);
 
@@ -229,6 +215,23 @@
 
 КонецПроцедуры
 
+Функция ИнициализироватьСоединение(Сервер) Экспорт
+	
+	НастройкиПрокси = НастройкиПриложения.Получить().Прокси;
+	Если НастройкиПрокси.ИспользоватьПрокси = Истина Тогда
+		Прокси = Новый ИнтернетПрокси(НастройкиПрокси.ПроксиПоУмолчанию);
+ 		Если НастройкиПрокси.ПроксиПоУмолчанию = Ложь Тогда
+			Прокси.Установить("http",НастройкиПрокси.Сервер,НастройкиПрокси.Порт,НастройкиПрокси.Пользователь,НастройкиПрокси.Пароль,НастройкиПрокси.ИспользоватьАутентификациюОС);
+ 		КонецЕсли;	
+		Соединение = Новый HTTPСоединение(Сервер,,,,Прокси);
+	Иначе
+		Соединение = Новый HTTPСоединение(Сервер);
+	КонецЕсли;
+
+	Возврат Соединение;
+
+КонецФункции	
+
 Функция РазобратьМаркерВерсии(Знач МаркерВерсии)
 
 	Перем ИндексВерсии;

src/Модули/Константы.os

@@ -3,10 +3,15 @@
 Перем ИмяФайлаСкриптаУстановки Экспорт;
 Перем ИмяФайлаСодержимогоПакета Экспорт;
 Перем ИмяФайлаМетаданныхПакета Экспорт;
+Перем СерверУдаленногоХранилища Экспорт;
+Перем ПутьВХранилище Экспорт;
+
 
 ///////////////////////////////////////////////////////////////
 
 ИмяФайлаСпецификацииПакета = "packagedef";
 ИмяФайлаСкриптаУстановки   = "_install_.os";
 ИмяФайлаСодержимогоПакета  = "content.zip";
-ИмяФайлаМетаданныхПакета   = "opm-metadata.xml";
+ИмяФайлаМетаданныхПакета   = "opm-metadata.xml";
+СерверУдаленногоХранилища  = "http://hub.oscript.io";
+ПутьВХранилище			   = "/download/";

tests/packagelist.os

@@ -0,0 +1,31 @@
+
+#Использовать asserts
+#Использовать "../src"
+
+Перем юТест;
+
+Функция ПолучитьСписокТестов(Знач Тестирование) Экспорт
+	
+	юТест = Тестирование;
+	
+	СписокТестов = Новый Массив;
+	
+	СписокТестов.Добавить("ТестДолжен_ПолучитьПакетыХаба");
+	
+	Возврат СписокТестов;
+	
+КонецФункции
+
+
+Функция ТестДолжен_ПолучитьПакетыХаба() Экспорт
+	
+	ПакетыХаба = Новый КэшПакетовХаба;
+	СписокПакетовХаба = ПакетыХаба.ПолучитьПакетыХаба();
+	
+	Ожидаем.Что(СписокПакетовХаба.Количество()).Больше(1);
+	Ожидаем.Что(СписокПакетовХаба.Получить("gitsync")).Равно(Истина);
+	Ожидаем.Что(СписокПакетовХаба.Получить("opm")).Равно(Истина);
+	Ожидаем.Что(СписокПакетовХаба.Получить("someelsepackadge")).Равно(Неопределено);
+	
+		
+КонецФункции