modules/output: produce empty files by default

Author: stasjok

lib/utils.nix

@@ -4,7 +4,15 @@
   _nixvimTests,
 }:
 with lib;
-{
+rec {
+  # Whether a string contains something other than whitespace
+  hasContent = str: builtins.match "[[:space:]]*" str == null;
+
+  # Concatenate a list of strings with a newline between each element
+  # skipping strings containing only whitespace characters
+  concatNonEmptyStringsNewline =
+    list: builtins.concatStringsSep "\n" (builtins.filter hasContent list);
+
   listToUnkeyedAttrs =
     list:
     builtins.listToAttrs (lib.lists.imap0 (idx: lib.nameValuePair "__unkeyed-${toString idx}") list);
@@ -118,4 +126,24 @@ with lib;
       ${string}
     end
   '';
+
+  # Wrap Vimscript for using in lua,
+  # but only if the string contains something other than whitespaces
+  wrapVimscriptForLua =
+    string:
+    optionalString (hasContent string) ''
+      vim.cmd([[
+      ${string}
+      ]])
+    '';
+
+  # Wrap lua script for using in Vimscript,
+  # but only if the string contains something other than whitespaces
+  wrapLuaForVimscript =
+    string:
+    optionalString (hasContent string) ''
+      lua << EOF
+      ${string}
+      EOF
+    '';
 }

modules/output.nix

@@ -1,4 +1,9 @@
-{ lib, config, ... }:
+{
+  lib,
+  config,
+  helpers,
+  ...
+}:
 with lib;
 let
   pluginWithConfigType = types.submodule {
@@ -99,25 +104,23 @@ in
 
   config =
     let
-      contentLua = ''
-        ${config.extraConfigLuaPre}
-        vim.cmd([[
-          ${config.extraConfigVim}
-        ]])
-        ${config.extraConfigLua}
-        ${config.extraConfigLuaPost}
-      '';
+      contentLua = helpers.concatNonEmptyStringsNewline [
+        config.extraConfigLuaPre
+        (helpers.wrapVimscriptForLua config.extraConfigVim)
+        config.extraConfigLua
+        config.extraConfigLuaPost
+      ];
 
-      contentVim = ''
-        lua << EOF
-          ${config.extraConfigLuaPre}
-        EOF
-        ${config.extraConfigVim}
-        lua << EOF
-          ${config.extraConfigLua}
-          ${config.extraConfigLuaPost}
-        EOF
-      '';
+      contentVim = helpers.concatNonEmptyStringsNewline [
+        (helpers.wrapLuaForVimscript config.extraConfigLuaPre)
+        config.extraConfigVim
+        (helpers.wrapLuaForVimscript (
+          helpers.concatNonEmptyStringsNewline [
+            config.extraConfigLua
+            config.extraConfigLuaPost
+          ]
+        ))
+      ];
     in
     {
       content = if config.type == "lua" then contentLua else contentVim;

modules/top-level/output.nix

@@ -107,16 +107,10 @@ with lib;
         }
       );
 
-      customRC =
-        let
-          hasContent = str: (builtins.match "[[:space:]]*" str) == null;
-        in
-        (optionalString (hasContent neovimConfig.neovimRcContent) ''
-          vim.cmd([[
-            ${neovimConfig.neovimRcContent}
-          ]])
-        '')
-        + config.content;
+      customRC = helpers.concatNonEmptyStringsNewline [
+        (helpers.wrapVimscriptForLua neovimConfig.neovimRcContent)
+        config.content
+      ];
 
       init = helpers.writeLua "init.lua" customRC;
 

tests/test-sources/modules/output.nix

@@ -1,7 +1,91 @@
+{ pkgs, helpers, ... }:
+let
+  inherit (pkgs) lib;
+in
 {
   extraLuaPackages = {
     extraLuaPackages = ps: [ ps.jsregexp ];
     # Make sure jsregexp is in LUA_PATH
     extraConfigLua = ''require("jsregexp")'';
   };
+
+  # Test that all extraConfigs are present in output
+  all-configs.module =
+    { config, ... }:
+    let
+      configs = {
+        extraConfigLuaPre = "string.format('extraConfigLuaPre1')";
+        extraConfigLua = "string.format('extraConfigLua2')";
+        extraConfigLuaPost = "string.format('extraConfigLuaPost3')";
+        extraConfigVim = "let g:var = 'extraConfigVim4'";
+      };
+      configAssertion = name: config: [
+        {
+          assertion = lib.hasInfix "extraConfigLuaPre1" config;
+          message = "Configuration file ${name} does not contain extraConfigLuaPre.";
+        }
+        {
+          assertion = lib.hasInfix "extraConfigLua2" config;
+          message = "Configuration file ${name} does not contain extraConfigLua.";
+        }
+        {
+          assertion = lib.hasInfix "extraConfigLuaPost3" config;
+          message = "Configuration file ${name} does not contain extraConfigLuaPost.";
+        }
+        {
+          assertion = lib.hasInfix "extraConfigVim4" config;
+          message = "Configuration file ${name} does not contain extraConfigVim.";
+        }
+      ];
+    in
+    configs
+    // {
+      files = {
+        "test.lua" = configs;
+        "test.vim" = configs;
+      };
+
+      # Plugin configs
+      extraPlugins = [
+        {
+          plugin = pkgs.emptyDirectory;
+          config = "let g:var = 'neovimRcContent5'";
+        }
+      ];
+
+      assertions =
+        configAssertion "init.lua" config.content
+        ++ configAssertion "test.lua" config.files."test.lua".content
+        ++ configAssertion "test.vim" config.files."test.vim".content
+        ++ [
+          # Only init.lua contains configuration from plugin definitions
+          {
+            # Plugin configs aren't available in options, only path to final init.lua
+            assertion = lib.hasInfix "neovimRcContent5" (builtins.readFile config.initPath);
+            message = "Configuration file init.lua does not contain plugin configs";
+          }
+        ];
+    };
+
+  files-default-empty.module =
+    { config, ... }:
+    {
+      files = {
+        # lua type
+        "test.lua" = { };
+        # vim type
+        "test.vim" = { };
+      };
+
+      assertions = [
+        {
+          assertion = !helpers.hasContent config.files."test.lua".content;
+          message = "Default content of test.lua file is expected to be empty.";
+        }
+        {
+          assertion = !helpers.hasContent config.files."test.vim".content;
+          message = "Default content of test.vim file is expected to be empty.";
+        }
+      ];
+    };
 }