Move Kotlin integration to a task-based approach

Even though adding an additional test root directory for Kotlin sources
might be the cleaner way, the IDE won't detect the tests by itself.
Therefore, this introduces the manual "copy task" workaround, which
moves the Kotlin test classes to a location where both the command line
and IDEs will pick them up.

Author: mannodermaus

android-junit5/src/main/groovy/de/mannodermaus/gradle/plugins/android_junit5/AndroidJUnit5Test.groovy

@@ -117,10 +117,6 @@ class AndroidJUnit5Test extends JavaExec {
                           // e.g. "build/intermediates/classes/test/debug/..."
                           variant.unitTestVariant.variantData.scope.javaOutputDir]
 
-      if (config.kotlinPluginApplied) {
-        testRootDirs += "$project.buildDir/tmp/kotlin-classes/${variant.name}UnitTest"
-      }
-
       project.logger.info(
           "$AndroidJUnitPlatformPlugin.LOG_TAG: Assembled JUnit 5 Task '$task.name':")
       testRootDirs.each {

android-junit5/src/main/groovy/de/mannodermaus/gradle/plugins/android_junit5/AndroidJUnitPlatformPlugin.groovy

@@ -3,6 +3,7 @@ package de.mannodermaus.gradle.plugins.android_junit5
 import com.android.build.gradle.api.BaseVariant
 import de.mannodermaus.gradle.plugins.android_junit5.jacoco.AndroidJUnit5JacocoExtension
 import de.mannodermaus.gradle.plugins.android_junit5.jacoco.AndroidJUnit5JacocoReport
+import de.mannodermaus.gradle.plugins.android_junit5.kotlin.AndroidJUnit5CopyKotlin
 import org.gradle.api.GradleException
 import org.gradle.api.Plugin
 import org.gradle.api.Project
@@ -198,13 +199,18 @@ class AndroidJUnitPlatformPlugin implements Plugin<Project> {
     def testVariants = project.android[allVariants].findAll { it.hasProperty("unitTestVariant") }
 
     def isJacocoApplied = projectConfig.jacocoPluginApplied
+    def isKotlinApplied = projectConfig.kotlinPluginApplied
 
     testVariants.each { variant ->
       def testTask = AndroidJUnit5Test.create(projectConfig, variant as BaseVariant)
 
       if (isJacocoApplied) {
         AndroidJUnit5JacocoReport.create(project, testTask)
       }
+
+      if (isKotlinApplied) {
+        AndroidJUnit5CopyKotlin.create(project, testTask)
+      }
     }
   }
 }

android-junit5/src/main/groovy/de/mannodermaus/gradle/plugins/android_junit5/kotlin/AndroidJUnit5CopyKotlin.groovy

@@ -0,0 +1,54 @@
+package de.mannodermaus.gradle.plugins.android_junit5.kotlin
+
+import com.android.build.gradle.api.BaseVariant
+import com.android.build.gradle.internal.scope.TaskConfigAction
+import com.android.build.gradle.internal.scope.VariantScope
+import de.mannodermaus.gradle.plugins.android_junit5.AndroidJUnit5Test
+import org.gradle.api.Project
+import org.gradle.api.plugins.JavaBasePlugin
+import org.gradle.api.tasks.Copy
+
+class AndroidJUnit5CopyKotlin extends Copy {
+
+  static AndroidJUnit5CopyKotlin create(Project project, AndroidJUnit5Test testTask) {
+    def configAction = new ConfigAction(project, testTask)
+    return project.tasks.create(configAction.getName(), configAction.getType(), configAction)
+  }
+
+  static class ConfigAction implements TaskConfigAction<AndroidJUnit5CopyKotlin> {
+
+    private static final String TASK_NAME_DEFAULT = "copyKotlinUnitTestClasses"
+    private static final String TASK_GROUP = JavaBasePlugin.VERIFICATION_GROUP
+
+    private final Project project
+    private final AndroidJUnit5Test testTask
+    private final BaseVariant variant
+    private final VariantScope scope
+
+    ConfigAction(Project project, AndroidJUnit5Test testTask) {
+      this.project = project
+      this.testTask = testTask
+      this.variant = testTask.variant
+      this.scope = variant.variantData.scope
+    }
+
+    @Override
+    String getName() {
+      return scope.getTaskName(TASK_NAME_DEFAULT)
+    }
+
+    @Override
+    Class<AndroidJUnit5CopyKotlin> getType() {
+      return AndroidJUnit5CopyKotlin.class
+    }
+
+    @Override
+    void execute(AndroidJUnit5CopyKotlin copyTask) {
+      copyTask.from "$project.buildDir/tmp/kotlin-classes/${variant.name}UnitTest"
+      copyTask.into "$project.buildDir/intermediates/classes/test/$variant.name"
+      copyTask.group = TASK_GROUP
+
+      testTask.dependsOn copyTask
+    }
+  }
+}

android-junit5/src/test/groovy/de/mannodermaus/gradle/plugins/android_junit5/BasePluginSpec.groovy

@@ -277,7 +277,7 @@ abstract class BasePluginSpec extends Specification {
     project.tasks.findByName("jacocoTestReportRelease") == null
   }
 
-  def "Presence of Kotlin plugin will add a dedicated Test Root Directory"() {
+  def "Application: Kotlin Integration"() {
     when:
     def project = factory.newProject(rootProject())
         .asAndroidApplication()
@@ -286,12 +286,46 @@ abstract class BasePluginSpec extends Specification {
         .buildAndEvaluate()
 
     then:
-    def runDebug = project.tasks.getByName("junitPlatformTestDebug") as AndroidJUnit5Test
-    def debugClasspath = runDebug.args[runDebug.args.indexOf("--scan-class-path") + 1]
-    assert debugClasspath.contains("/build/tmp/kotlin-classes/debugUnitTest")
+    project.tasks.getByName("copyKotlinUnitTestClassesDebug")
+    project.tasks.getByName("copyKotlinUnitTestClassesRelease")
+  }
+
+  def "Library: Kotlin Integration"() {
+    when:
+    def project = factory.newProject(rootProject())
+        .asAndroidLibrary()
+        .applyJunit5Plugin()
+        .applyKotlinPlugin()
+        .buildAndEvaluate()
+
+    then:
+    project.tasks.getByName("copyKotlinUnitTestClassesDebug")
+    project.tasks.getByName("copyKotlinUnitTestClassesRelease")
+  }
 
-    def runRelease = project.tasks.getByName("junitPlatformTestRelease") as AndroidJUnit5Test
-    def releaseClasspath = runRelease.args[runRelease.args.indexOf("--scan-class-path") + 1]
-    assert releaseClasspath.contains("/build/tmp/kotlin-classes/releaseUnitTest")
+  def "Application: Kotlin Tasks not added if plugin absent"() {
+    when:
+    def project = factory.newProject(rootProject())
+        .asAndroidApplication()
+        .applyJunit5Plugin()
+        .applyKotlinPlugin(false)
+        .buildAndEvaluate()
+
+    then:
+    project.tasks.findByName("copyKotlinUnitTestClassesDebug") == null
+    project.tasks.findByName("copyKotlinUnitTestClassesRelease") == null
+  }
+
+  def "Library: Kotlin Tasks not added if plugin absent"() {
+    when:
+    def project = factory.newProject(rootProject())
+        .asAndroidLibrary()
+        .applyJunit5Plugin()
+        .applyKotlinPlugin(false)
+        .buildAndEvaluate()
+
+    then:
+    project.tasks.findByName("copyKotlinUnitTestClassesDebug") == null
+    project.tasks.findByName("copyKotlinUnitTestClassesRelease") == null
   }
 }

gradle.properties

@@ -5,7 +5,7 @@ android.injected.build.model.only.versioned = 3
 
 # Artifact configuration (common)
 GROUP_ID                                    = de.mannodermaus.gradle.plugins
-VERSION_NAME                                = 1.0.12-SNAPSHOT
+VERSION_NAME                                = 1.0.11-SNAPSHOT
 VCS_URL                                     = https://github.com/mannodermaus/android-junit5
 
 # Artifact configuration (plugin)