C#: Move the isCallOnReponseHeaderAccess out of each disjunkt.

Author: michaelnebel

csharp/ql/lib/semmle/code/csharp/security/MissingXFrameOptionsQuery.qll

@@ -60,45 +60,53 @@ private predicate isCallOnResponseHeadersAccess(Call call) {
   )
 }
 
-/** Gets an expression that configures a clickjacking-related response header. */
-Call getAClickjackingHeaderWrite() {
+private predicate isClickjackingHeaderCall(MethodCall call) {
   (
-    result.getTarget() = any(SystemWebHttpResponseClass r).getAppendHeaderMethod() or
-    result.getTarget() = any(SystemWebHttpResponseClass r).getAddHeaderMethod()
+    call.getTarget() = any(SystemWebHttpResponseClass r).getAppendHeaderMethod() or
+    call.getTarget() = any(SystemWebHttpResponseClass r).getAddHeaderMethod()
   ) and
   (
-    isXFrameOptionsHeaderNameExpr(result.getArgumentForName("name"))
+    isXFrameOptionsHeaderNameExpr(call.getArgumentForName("name"))
     or
-    isContentSecurityPolicyHeaderNameExpr(result.getArgumentForName("name")) and
-    containsFrameAncestorsDirectiveExpr(result.getArgumentForName("value"))
+    isContentSecurityPolicyHeaderNameExpr(call.getArgumentForName("name")) and
+    containsFrameAncestorsDirectiveExpr(call.getArgumentForName("value"))
   )
-  or
-  result.getTarget().hasUndecoratedName(["Append", "Add", "TryAdd"]) and
-  isCallOnResponseHeadersAccess(result) and
+}
+
+private predicate isClickjackingHeaderDictionaryLikeWrite(Call call) {
   (
-    isXFrameOptionsHeaderNameExpr(result.getArgumentForName("key"))
+    call.getTarget().hasUndecoratedName(["Append", "Add", "TryAdd"])
     or
-    isContentSecurityPolicyHeaderNameExpr(result.getArgumentForName("key")) and
-    containsFrameAncestorsDirectiveExpr(result.getArgumentForName("value"))
+    call.(IndexerCall).getTarget() instanceof Setter
+  ) and
+  (
+    isXFrameOptionsHeaderNameExpr(call.getArgumentForName("key"))
+    or
+    isContentSecurityPolicyHeaderNameExpr(call.getArgumentForName("key")) and
+    containsFrameAncestorsDirectiveExpr(call.getArgumentForName("value"))
   )
-  or
-  result.getTarget() instanceof Setter and
-  isCallOnResponseHeadersAccess(result) and
+}
+
+private predicate isClickjackingPropertyWrite(Call c) {
+  c.getTarget() instanceof Setter and
   (
-    isXFrameOptionsHeaderNameExpr(result.getArgumentForName("key"))
+    c.(PropertyCall).getProperty() =
+      any(MicrosoftAspNetCoreHttpIHeaderDictionary dic).getXFrameOptionsProperty()
     or
-    isContentSecurityPolicyHeaderNameExpr(result.getArgumentForName("key")) and
-    containsFrameAncestorsDirectiveExpr(result.getArgumentForName("value"))
+    c.(PropertyCall).getProperty() =
+      any(MicrosoftAspNetCoreHttpIHeaderDictionary dic).getContentSecurityPolicyProperty() and
+    containsFrameAncestorsDirectiveExpr(c.getArgumentForName("value"))
   )
+}
+
+/** Gets an expression that configures a clickjacking-related response header. */
+Call getAClickjackingHeaderWrite() {
+  isClickjackingHeaderCall(result)
   or
-  result.getTarget() instanceof Setter and
   isCallOnResponseHeadersAccess(result) and
   (
-    result.(PropertyCall).getProperty() =
-      any(MicrosoftAspNetCoreHttpIHeaderDictionary dic).getXFrameOptionsProperty()
+    isClickjackingHeaderDictionaryLikeWrite(result)
     or
-    result.(PropertyCall).getProperty() =
-      any(MicrosoftAspNetCoreHttpIHeaderDictionary dic).getContentSecurityPolicyProperty() and
-    containsFrameAncestorsDirectiveExpr(result.getArgumentForName("value"))
+    isClickjackingPropertyWrite(result)
   )
 }