Type inference: Revert inverse append changes

Author: hvitved

shared/typeinference/codeql/typeinference/internal/TypeInference.qll

@@ -70,7 +70,6 @@ overlay[local?]
 module;
 
 private import codeql.util.Location
-private import codeql.util.Strings
 
 /** Provides the input to `Make1`. */
 signature module InputSig1<LocationSig Location> {
@@ -1435,18 +1434,6 @@ module Make1<LocationSig Location, InputSig1<Location> Input1> {
         private module SatisfiesParameterConstraint =
           SatisfiesConstraint<RelevantAccess, RelevantTarget, SatisfiesParameterConstraintInput>;
 
-        private module InverseAppend2Input implements InverseAppend2InputSig {
-          class C1 = Declaration;
-
-          class C2 = AccessPosition;
-
-          class Result = TypeParameter;
-
-          predicate prefixCandidate(string prefix, C1 c1, C2 c2, Result res) {
-            argRootTypeSatisfiesTargetTypeCand(_, c1, c2, res, prefix)
-          }
-        }
-
         /**
          * Holds if the (transitive) base type `t` at `path` of `a` in environment `e`
          * for some `AccessPosition` matches the type parameter `tp`, which is used in
@@ -1483,11 +1470,12 @@ module Make1<LocationSig Location, InputSig1<Location> Input1> {
         predicate baseTypeMatch(
           Access a, AccessEnvironment e, Declaration target, TypePath path, Type t, TypeParameter tp
         ) {
-          exists(AccessPosition apos, TypePath pathFull |
+          exists(AccessPosition apos, TypePath pathToTp |
+            argRootTypeSatisfiesTargetTypeCand(_, target, pragma[only_bind_into](apos), tp, pathToTp) and
             SatisfiesParameterConstraint::satisfiesConstraint(MkRelevantAccess(a,
                 pragma[only_bind_into](apos), e),
-              MkRelevantTarget(target, pragma[only_bind_into](apos)), pathFull, t) and
-            InverseAppend2<InverseAppend2Input>::inverseAppend(pathFull, _, path, target, apos, tp) and
+              MkRelevantTarget(target, pragma[only_bind_into](apos)), pathToTp.appendInverse(path),
+              t) and
             hasNotTypeArgument(a, target, tp)
           )
         }
@@ -1642,29 +1630,15 @@ module Make1<LocationSig Location, InputSig1<Location> Input1> {
         constrainedTp != tp
       }
 
-      private module InverseAppend3Input implements InverseAppend3InputSig {
-        class C1 = Declaration;
-
-        class C2 = TypeParameter;
-
-        class C3 = TypeMention;
-
-        class Result = TypeParameter;
-
-        predicate prefixCandidate(string prefix, C1 c1, C2 c2, C3 c3, Result res) {
-          typeParameterConstraintHasTypeParameter(c1, c2, c3, prefix, res)
-        }
-      }
-
       pragma[nomagic]
       private predicate typeConstraintBaseTypeMatch(
         Access a, AccessEnvironment e, Declaration target, TypePath path, Type t, TypeParameter tp
       ) {
         hasNotTypeArgument(a, target, tp) and
-        exists(TypeParameter constrainedTp, TypeMention constraint, TypePath pathFull |
-          AccessConstraint::satisfiesConstraint(a, e, target, constrainedTp, constraint, pathFull, t) and
-          InverseAppend3<InverseAppend3Input>::inverseAppend(pathFull, _, path, target,
-            constrainedTp, constraint, tp)
+        exists(TypeMention constraint, TypeParameter constrainedTp, TypePath pathToTp |
+          typeParameterConstraintHasTypeParameter(target, constrainedTp, constraint, pathToTp, tp) and
+          AccessConstraint::satisfiesConstraint(a, e, target, constrainedTp, constraint,
+            pathToTp.appendInverse(path), t)
         )
       }
 

shared/util/codeql/util/Strings.qll

@@ -91,194 +91,3 @@ int asciiPrintable(string char) {
             .charAt(_)
     )
 }
-
-/**
- * Escapes all characters in `s` that have special meaning in regular expressions.
- */
-bindingset[s]
-string regexpEscape(string s) {
-  result = s.regexpReplaceAll("([\\\\.*+?\\[^\\]$(){}=!<>|:\\-])", "\\\\$1")
-}
-
-/** Provides the input to `InverseAppend`. */
-signature module InverseAppendInputSig {
-  /** A prefix matching result. */
-  bindingset[this]
-  class Result;
-
-  /**
-   * Holds if `prefix` is a prefix candidate with resulting value `res`.
-   */
-  predicate prefixCandidate(string prefix, Result res);
-}
-
-/** Provides the `inverseAppend` predicate. */
-module InverseAppend<InverseAppendInputSig Input> {
-  /**
-   * Holds if `s = prefix + suffix` with resulting value `res`.
-   *
-   * The predicate avoids unnecessary result fan-out by first constraining the
-   * prefix using a regular expression match.
-   */
-  bindingset[s]
-  predicate inverseAppend(string s, string prefix, string suffix, Input::Result res) {
-    exists(string regexp |
-      regexp =
-        "(" +
-          strictconcat(string prefixCand |
-            Input::prefixCandidate(prefixCand, _)
-          |
-            regexpEscape(prefixCand), "|"
-          ) + ").*" and
-      prefix = s.regexpCapture(regexp, 1) and
-      s = prefix + suffix and
-      Input::prefixCandidate(prefix, res)
-    )
-  }
-}
-
-/** Provides the input to `InverseAppend1`. */
-signature module InverseAppend1InputSig {
-  /** A prefix matching context. */
-  bindingset[this]
-  class C;
-
-  /** A prefix matching result. */
-  bindingset[this]
-  class Result;
-
-  /**
-   * Holds if `prefix` is a prefix candidate in the context `c`
-   * with resulting value `res`.
-   */
-  predicate prefixCandidate(string prefix, C c, Result res);
-}
-
-/** Provides the `inverseAppend` predicate. */
-module InverseAppend1<InverseAppend1InputSig Input> {
-  /**
-   * Holds if `s = prefix + suffix` in the context `c` with resulting
-   * value `res`.
-   *
-   * The predicate avoids unnecessary result fan-out by first constraining the
-   * prefix using a regular expression match.
-   */
-  bindingset[s]
-  predicate inverseAppend(string s, string prefix, string suffix, Input::C c, Input::Result res) {
-    exists(string regexp |
-      regexp =
-        "(" +
-          strictconcat(string prefixCand |
-            Input::prefixCandidate(prefixCand, c, _)
-          |
-            regexpEscape(prefixCand), "|"
-          ) + ").*" and
-      prefix = s.regexpCapture(regexp, 1) and
-      s = prefix + suffix and
-      Input::prefixCandidate(prefix, c, res)
-    )
-  }
-}
-
-/** Provides the input to `InverseAppend2`. */
-signature module InverseAppend2InputSig {
-  /** A prefix matching context. */
-  bindingset[this]
-  class C1;
-
-  /** A prefix matching context. */
-  bindingset[this]
-  class C2;
-
-  /** A prefix matching result. */
-  bindingset[this]
-  class Result;
-
-  /**
-   * Holds if `prefix` is a prefix candidate in the context `(c1, c2)`
-   * with resulting value `res`.
-   */
-  predicate prefixCandidate(string prefix, C1 c1, C2 c2, Result res);
-}
-
-/** Provides the `inverseAppend` predicate. */
-module InverseAppend2<InverseAppend2InputSig Input> {
-  /**
-   * Holds if `s = prefix + suffix` in the context `(c1, c2)` with resulting
-   * value `res`.
-   *
-   * The predicate avoids unnecessary result fan-out by first constraining the
-   * prefix using a regular expression match.
-   */
-  bindingset[s]
-  predicate inverseAppend(
-    string s, string prefix, string suffix, Input::C1 c1, Input::C2 c2, Input::Result res
-  ) {
-    exists(string regexp |
-      regexp =
-        "(" +
-          strictconcat(string prefixCand |
-            Input::prefixCandidate(prefixCand, c1, c2, _)
-          |
-            regexpEscape(prefixCand), "|"
-          ) + ").*" and
-      prefix = s.regexpCapture(regexp, 1) and
-      s = prefix + suffix and
-      Input::prefixCandidate(prefix, c1, c2, res)
-    )
-  }
-}
-
-/** Provides the input to `InverseAppend3`. */
-signature module InverseAppend3InputSig {
-  /** A prefix matching context. */
-  bindingset[this]
-  class C1;
-
-  /** A prefix matching context. */
-  bindingset[this]
-  class C2;
-
-  /** A prefix matching context. */
-  bindingset[this]
-  class C3;
-
-  /** A prefix matching result. */
-  bindingset[this]
-  class Result;
-
-  /**
-   * Holds if `prefix` is a prefix candidate in the context `(c1, c2, c3)`
-   * with resulting value `res`.
-   */
-  predicate prefixCandidate(string prefix, C1 c1, C2 c2, C3 c3, Result res);
-}
-
-/** Provides the `inverseAppend` predicate. */
-module InverseAppend3<InverseAppend3InputSig Input> {
-  /**
-   * Holds if `s = prefix + suffix` in the context `(c1, c2, c3)` with resulting
-   * value `res`.
-   *
-   * The predicate avoids unnecessary result fan-out by first constraining the
-   * prefix using a regular expression match.
-   */
-  bindingset[s]
-  predicate inverseAppend(
-    string s, string prefix, string suffix, Input::C1 c1, Input::C2 c2, Input::C3 c3,
-    Input::Result res
-  ) {
-    exists(string regexp |
-      regexp =
-        "(" +
-          strictconcat(string prefixCand |
-            Input::prefixCandidate(prefixCand, c1, c2, c3, _)
-          |
-            regexpEscape(prefixCand), "|"
-          ) + ").*" and
-      prefix = s.regexpCapture(regexp, 1) and
-      s = prefix + suffix and
-      Input::prefixCandidate(prefix, c1, c2, c3, res)
-    )
-  }
-}