Declarations5: add RULE-8-5

Author: knewbury01

.vscode/tasks.json

@@ -206,6 +206,7 @@
                 "Declarations",
                 "Declarations1",
                 "Declarations2",
+                "Declarations5",
                 "Exceptions1",
                 "Exceptions2",
                 "Expressions",

c/misra/src/rules/RULE-8-5/ExternalObjectOrFunctionNotDeclaredInOneFile.ql

@@ -0,0 +1,43 @@
+/**
+ * @id c/misra/external-object-or-function-not-declared-in-one-file
+ * @name RULE-8-5: An external object or function shall be declared once in one and only one file
+ * @description Declarations in multiple files can lead to unexpected program behaviour.
+ * @kind problem
+ * @precision very-high
+ * @problem.severity warning
+ * @tags external/misra/id/rule-8-5
+ *       correctness
+ *       external/misra/obligation/required
+ */
+
+import cpp
+import codingstandards.c.misra
+
+from DeclarationEntry de, DeclarationEntry otherDeclaration, string kind
+where
+  not isExcluded(de, Declarations5Package::externalObjectOrFunctionNotDeclaredInOneFileQuery()) and
+  //this rule applies to non-defining declarations only
+  not de.isDefinition() and
+  not otherDeclaration.isDefinition() and
+  exists(Declaration d |
+    de.getDeclaration() = d and
+    otherDeclaration.getDeclaration() = d and
+    de.getFile() != otherDeclaration.getFile()
+  ) and
+  (
+    de.getDeclaration() instanceof Function and kind = "function"
+    or
+    de.getDeclaration() instanceof Variable and
+    not de.getDeclaration() instanceof Parameter and
+    kind = "variable"
+  ) and
+  // Apply an ordering based on location to enforce that (de1, de2) = (de2, de1) and we only report (de1, de2).
+  (
+    de.getFile().getAbsolutePath() < otherDeclaration.getFile().getAbsolutePath()
+    or
+    de.getFile().getAbsolutePath() = otherDeclaration.getFile().getAbsolutePath() and
+    de.getLocation().getStartLine() < otherDeclaration.getLocation().getStartLine()
+  )
+select de,
+  "The " + kind + " declaration " + de.getName() +
+    " is declared in multiple files and has an additional $@.", otherDeclaration, "declaration"

c/misra/test/rules/RULE-8-5/ExternalObjectOrFunctionNotDeclaredInOneFile.expected

@@ -0,0 +1,2 @@
+| test.c:8:12:8:13 | declaration of g3 | The variable declaration g3 is declared in multiple files and has an additional $@. | test1.c:1:12:1:13 | declaration of g3 | declaration |
+| test.h:1:12:1:12 | declaration of g | The variable declaration g is declared in multiple files and has an additional $@. | test1.h:1:12:1:12 | declaration of g | declaration |

c/misra/test/rules/RULE-8-5/ExternalObjectOrFunctionNotDeclaredInOneFile.qlref

@@ -0,0 +1 @@
+rules/RULE-8-5/ExternalObjectOrFunctionNotDeclaredInOneFile.ql

c/misra/test/rules/RULE-8-5/test.c

@@ -0,0 +1,8 @@
+#include "test.h"
+#include "test1.h"
+
+int g = 1; // COMPLIANT
+
+extern int g1; // COMPLIANT
+
+extern int g3; // NON_COMPLIANT

c/misra/test/rules/RULE-8-5/test.h

@@ -0,0 +1,3 @@
+extern int g; // NON_COMPLIANT
+
+int g2; // COMPLIANT

c/misra/test/rules/RULE-8-5/test1.c

@@ -0,0 +1 @@
+extern int g3; // NON_COMPLIANT

c/misra/test/rules/RULE-8-5/test1.h

@@ -0,0 +1,3 @@
+extern int g; // NON_COMPLIANT
+
+int g2; // COMPLIANT

cpp/common/src/codingstandards/cpp/exclusions/c/Declarations5.qll

@@ -0,0 +1,25 @@
+//** THIS FILE IS AUTOGENERATED, DO NOT MODIFY DIRECTLY.  **/
+import cpp
+import RuleMetadata
+import codingstandards.cpp.exclusions.RuleMetadata
+
+newtype Declarations5Query = TExternalObjectOrFunctionNotDeclaredInOneFileQuery()
+
+predicate isDeclarations5QueryMetadata(Query query, string queryId, string ruleId) {
+  query =
+    // `Query` instance for the `externalObjectOrFunctionNotDeclaredInOneFile` query
+    Declarations5Package::externalObjectOrFunctionNotDeclaredInOneFileQuery() and
+  queryId =
+    // `@id` for the `externalObjectOrFunctionNotDeclaredInOneFile` query
+    "c/misra/external-object-or-function-not-declared-in-one-file" and
+  ruleId = "RULE-8-5"
+}
+
+module Declarations5Package {
+  Query externalObjectOrFunctionNotDeclaredInOneFileQuery() {
+    //autogenerate `Query` type
+    result =
+      // `Query` type for `externalObjectOrFunctionNotDeclaredInOneFile` query
+      TQueryC(TDeclarations5PackageQuery(TExternalObjectOrFunctionNotDeclaredInOneFileQuery()))
+  }
+}

cpp/common/src/codingstandards/cpp/exclusions/c/RuleMetadata.qll

@@ -15,6 +15,7 @@ import Contracts4
 import Declarations1
 import Declarations2
 import Declarations3
+import Declarations5
 import Expressions
 import IO1
 import IO2
@@ -52,6 +53,7 @@ newtype TCQuery =
   TDeclarations1PackageQuery(Declarations1Query q) or
   TDeclarations2PackageQuery(Declarations2Query q) or
   TDeclarations3PackageQuery(Declarations3Query q) or
+  TDeclarations5PackageQuery(Declarations5Query q) or
   TExpressionsPackageQuery(ExpressionsQuery q) or
   TIO1PackageQuery(IO1Query q) or
   TIO2PackageQuery(IO2Query q) or
@@ -89,6 +91,7 @@ predicate isQueryMetadata(Query query, string queryId, string ruleId) {
   isDeclarations1QueryMetadata(query, queryId, ruleId) or
   isDeclarations2QueryMetadata(query, queryId, ruleId) or
   isDeclarations3QueryMetadata(query, queryId, ruleId) or
+  isDeclarations5QueryMetadata(query, queryId, ruleId) or
   isExpressionsQueryMetadata(query, queryId, ruleId) or
   isIO1QueryMetadata(query, queryId, ruleId) or
   isIO2QueryMetadata(query, queryId, ruleId) or