Implement SetTimberUserContext plug (#1101)

* Created and applied a SetTimberUserContext plug
* Implemented User.full_name/1 function
* Added `SetTimberUserContext` to `groups_for_modules` in "Web – Plugs" list.

Author: tteerawat

lib/code_corps/guardian.ex

@@ -17,24 +17,6 @@ defmodule CodeCorps.Guardian do
   def resource_from_claims(_), do: {:error, :missing_subject}
 
   defp resource_from_subject("Project:" <> id), do: {:ok, Repo.get(Project, id)}
-  defp resource_from_subject("User:" <> id) do
-    user = Repo.get(User, id)
-
-    if user do
-      name = full_name(user)
-      %Timber.Contexts.UserContext{id: user.id, email: user.email, name: name}
-      |> Timber.add_context()
-    end
-
-    {:ok, user}
-  end
+  defp resource_from_subject("User:" <> id), do: {:ok, Repo.get(User, id)}
   defp resource_from_subject(_), do: {:error, :unknown_resource_type}
-
-  defp full_name(%User{first_name: nil, last_name: nil}), do: ""
-  defp full_name(%User{first_name: first_name, last_name: nil}), do: first_name
-  defp full_name(%User{first_name: nil, last_name: last_name}), do: last_name
-  defp full_name(%User{first_name: first_name, last_name: last_name}) do
-    first_name <> " " <> last_name
-  end
-  defp full_name(_), do: ""
 end

lib/code_corps/model/user.ex

@@ -68,6 +68,15 @@ defmodule CodeCorps.User do
     timestamps()
   end
 
+  @doc """
+  Returns full name of the given user.
+  """
+  def full_name(%__MODULE__{first_name: first_name, last_name: last_name}) do
+    [first_name, last_name]
+    |> Enum.map_join(" ", &to_string/1)
+    |> String.trim()
+  end
+
   @doc """
   Builds a changeset based on the `struct` and `params`.
   """

lib/code_corps_web/plugs/set_timber_user_context.ex

@@ -0,0 +1,25 @@
+defmodule CodeCorpsWeb.Plug.SetTimberUserContext do
+  @moduledoc """
+  Captures user context.
+  """
+
+  @behaviour Plug
+
+  alias CodeCorps.User
+
+  @impl true
+  def init(opts), do: opts
+
+  @impl true
+  def call(%{assigns: %{current_user: user}} = conn, _), do: add_context(conn, user)
+  def call(conn, _), do: conn
+
+  @impl false
+  def add_context(conn, %User{} = user) do
+    %Timber.Contexts.UserContext{id: user.id, email: user.email, name: User.full_name(user)}
+    |> Timber.add_context()
+
+    conn
+  end
+  def add_context(conn, _), do: conn
+end

lib/code_corps_web/router.ex

@@ -26,6 +26,7 @@ defmodule CodeCorpsWeb.Router do
 
   pipeline :current_user do
     plug CodeCorpsWeb.Plug.CurrentUser
+    plug CodeCorpsWeb.Plug.SetTimberUserContext
     plug CodeCorpsWeb.Plug.SetSentryUserContext
     plug CodeCorpsWeb.Plug.AnalyticsIdentify
   end

mix.exs

@@ -232,7 +232,8 @@ defmodule CodeCorps.Mixfile do
         CodeCorpsWeb.Plug.DataToAttributes,
         CodeCorpsWeb.Plug.IdsToIntegers,
         CodeCorpsWeb.Plug.Segment,
-        CodeCorpsWeb.Plug.SetSentryUserContext
+        CodeCorpsWeb.Plug.SetSentryUserContext,
+        CodeCorpsWeb.Plug.SetTimberUserContext
       ],
 
       "Miscellaneous": [

test/lib/code_corps/model/user_test.exs

@@ -6,20 +6,39 @@ defmodule CodeCorps.UserTest do
   @valid_attrs %{email: "test@user.com", password: "somepassword", username: "testuser"}
   @invalid_attrs %{}
 
-  test "changeset with valid attributes" do
-    changeset = User.changeset(%User{}, @valid_attrs)
-    assert changeset.valid?
+  describe "full_name/1" do
+    test "returns full name correctly" do
+      names = [
+        {"Josh", "Smith", "Josh Smith"},
+        {"Josh", nil,     "Josh"},
+        {nil,    "Smith", "Smith"},
+        {nil,    nil,     ""},
+        {"",     "",      ""}
+      ]
+      Enum.each names, fn({first_name, last_name, expected_full_name}) ->
+        user = build(:user, first_name: first_name, last_name: last_name)
+
+        assert User.full_name(user) == expected_full_name
+      end
+    end
   end
 
-  test "changeset with invalid attributes" do
-    changeset = User.changeset(%User{}, @invalid_attrs)
-    refute changeset.valid?
-  end
+  describe "changeset/2" do
+    test "changeset with valid attributes" do
+      changeset = User.changeset(%User{}, @valid_attrs)
+      assert changeset.valid?
+    end
 
-  test "changeset with invalid email" do
-    attrs = Map.put(@valid_attrs, :email, "notanemail")
-    changeset = User.changeset(%User{}, attrs)
-    assert_error_message(changeset, :email, "has invalid format")
+    test "changeset with invalid attributes" do
+      changeset = User.changeset(%User{}, @invalid_attrs)
+      refute changeset.valid?
+    end
+
+    test "changeset with invalid email" do
+      attrs = Map.put(@valid_attrs, :email, "notanemail")
+      changeset = User.changeset(%User{}, attrs)
+      assert_error_message(changeset, :email, "has invalid format")
+    end
   end
 
   describe "registration_changeset" do

test/lib/code_corps_web/plugs/set_timber_user_context_test.exs

@@ -0,0 +1,57 @@
+defmodule CodeCorpsWeb.Plug.SetTimberUserContextTest do
+  use CodeCorpsWeb.ConnCase
+
+  alias CodeCorpsWeb.Plug.SetTimberUserContext
+
+  @opts SetTimberUserContext.init([])
+
+  describe "init/1" do
+    test "returns the given options" do
+      assert SetTimberUserContext.init([]) == []
+    end
+  end
+
+  describe "call/2" do
+    test "adds user context when current_user is set" do
+      user = insert(:user, first_name: "Josh", last_name: "Smith")
+      conn = build_conn() |> assign(:current_user, user)
+
+      result = SetTimberUserContext.call(conn, @opts)
+
+      assert result == conn
+      assert Timber.CurrentContext.load() ==
+               %{user: %{id: to_string(user.id), name: "Josh Smith", email: user.email}}
+    end
+
+    test "adds nothing when current_user is not set" do
+      conn = build_conn()
+
+      result = SetTimberUserContext.call(conn, @opts)
+
+      assert result == conn
+      assert Timber.CurrentContext.load() == %{}
+    end
+  end
+
+  describe "add_context/2" do
+    test "adds user context correctly when given user is valid" do
+      user = insert(:user, first_name: "Josh", last_name: nil)
+      conn = build_conn()
+
+      result = SetTimberUserContext.add_context(conn, user)
+
+      assert result == conn
+      assert Timber.CurrentContext.load() ==
+               %{user: %{id: to_string(user.id), name: "Josh", email: user.email}}
+    end
+
+    test "adds nothing when given user is invalid" do
+      conn = build_conn()
+
+      result = SetTimberUserContext.add_context(conn, nil)
+
+      assert result == conn
+      assert Timber.CurrentContext.load() == %{}
+    end
+  end
+end