CLJS-2008: Self-host: backport fixes to threading macros

Author: mfikes

src/main/clojure/cljs/core.cljc

@@ -449,10 +449,13 @@
      [expr & clauses]
      (core/assert (even? (count clauses)))
      (core/let [g (gensym)
-                pstep (core/fn [[test step]] `(if ~test (-> ~g ~step) ~g))]
+                steps (map (core/fn [[test step]] `(if ~test (-> ~g ~step) ~g))
+                        (partition 2 clauses))]
        `(let [~g ~expr
-              ~@(interleave (repeat g) (map pstep (partition 2 clauses)))]
-          ~g))))
+              ~@(interleave (repeat g) (butlast steps))]
+          ~(if (empty? steps)
+             g
+             (last steps))))))
 
 #?(:cljs
    (core/defmacro cond->>
@@ -463,10 +466,13 @@
      [expr & clauses]
      (core/assert (even? (count clauses)))
      (core/let [g (gensym)
-                pstep (core/fn [[test step]] `(if ~test (->> ~g ~step) ~g))]
+                steps (map (core/fn [[test step]] `(if ~test (->> ~g ~step) ~g))
+                        (partition 2 clauses))]
        `(let [~g ~expr
-              ~@(interleave (repeat g) (map pstep (partition 2 clauses)))]
-          ~g))))
+              ~@(interleave (repeat g) (butlast steps))]
+          ~(if (empty? steps)
+             g
+             (last steps))))))
 
 #?(:cljs
    (core/defmacro as->
@@ -475,30 +481,38 @@
      successive form, returning the result of the last form."
      [expr name & forms]
      `(let [~name ~expr
-            ~@(interleave (repeat name) forms)]
-        ~name)))
+            ~@(interleave (repeat name) (butlast forms))]
+        ~(if (empty? forms)
+           name
+           (last forms)))))
 
 #?(:cljs
    (core/defmacro some->
      "When expr is not nil, threads it into the first form (via ->),
      and when that result is not nil, through the next etc"
      [expr & forms]
      (core/let [g (gensym)
-                pstep (core/fn [step] `(if (nil? ~g) nil (-> ~g ~step)))]
+                steps (map (core/fn [step] `(if (nil? ~g) nil (-> ~g ~step)))
+                        forms)]
        `(let [~g ~expr
-              ~@(interleave (repeat g) (map pstep forms))]
-          ~g))))
+              ~@(interleave (repeat g) (butlast steps))]
+          ~(if (empty? steps)
+             g
+             (last steps))))))
 
 #?(:cljs
    (core/defmacro some->>
      "When expr is not nil, threads it into the first form (via ->>),
      and when that result is not nil, through the next etc"
      [expr & forms]
      (core/let [g (gensym)
-                pstep (core/fn [step] `(if (nil? ~g) nil (->> ~g ~step)))]
+                steps (map (core/fn [step] `(if (nil? ~g) nil (->> ~g ~step)))
+                        forms)]
        `(let [~g ~expr
-              ~@(interleave (repeat g) (map pstep forms))]
-          ~g))))
+              ~@(interleave (repeat g) (butlast steps))]
+          ~(if (empty? steps)
+             g
+             (last steps))))))
 
 #?(:cljs
    (core/defmacro if-some

src/test/cljs/cljs/core_test.cljs

@@ -491,6 +491,50 @@
       (is (= expected (hash uuid)))
       (is (= expected (.-__hash uuid))))))
 
+(def constantly-nil (constantly nil))
+
+(deftest some->test
+  (is (nil? (some-> nil)))
+  (is (= 0 (some-> 0)))
+  (is (= -1 (some-> 1 (- 2))))
+  (is (nil? (some-> 1 constantly-nil (- 2)))))
+
+(deftest some->>test
+  (is (nil? (some->> nil)))
+  (is (= 0 (some->> 0)))
+  (is (= 1 (some->> 1 (- 2))))
+  (is (nil? (some->> 1 constantly-nil (- 2)))))
+
+(deftest cond->test
+  (is (= 0 (cond-> 0)))
+  (is (= -1 (cond-> 0 true inc true (- 2))))
+  (is (= 0 (cond-> 0 false inc)))
+  (is (= -1 (cond-> 1 true (- 2) false inc))))
+
+(deftest cond->>test
+  (is (= 0 (cond->> 0)))
+  (is (= 1 (cond->> 0 true inc true (- 2))))
+  (is (= 0 (cond->> 0 false inc)))
+  (is (= 1 (cond->> 1 true (- 2) false inc))))
+
+(deftest as->test
+  (is (= 0 (as-> 0 x)))
+  (is (= 1 (as-> 0 x (inc x))))
+  (is (= 2 (as-> [0 1] x
+             (map inc x)
+             (reverse x)
+             (first x)))))
+
+(deftest threading-loop-recur
+  (is (nil? (loop []
+              (as-> 0 x
+                (when-not (zero? x)
+                  (recur))))))
+  (is (nil? (loop [x nil] (some-> x recur))))
+  (is (nil? (loop [x nil] (some->> x recur))))
+  (is (= 0 (loop [x 0] (cond-> x false recur))))
+  (is (= 0 (loop [x 0] (cond->> x false recur)))))
+
 ;; =============================================================================
 ;; Tickets