feat(social): adds db for latest & top author interactions

Author: rafaeldelboni

docker/docker-compose.yml

@@ -1,5 +1,3 @@
-version: "3.7"
-
 services:
   db:
     image: postgres:14

src/codes/clj/docs/backend/adapters/db/postgres.clj

@@ -12,6 +12,15 @@
    :author/avatar-url avatar-url
    :author/created-at created-at})
 
+(defn db->author+interaction
+  {:malli/schema [:=> [:cat [:sequential schemas.db/Author+InteractionsRow]]
+                  [:sequential schemas.model.social/Author+Interactions]]}
+  [db-rows]
+  (map (fn [{:keys [interactions] :as author}]
+         (assoc (db->author author)
+                :author/interactions interactions))
+       db-rows))
+
 (defn db->note
   {:malli/schema [:=> [:cat [:maybe schemas.db/Row]] [:maybe schemas.model.social/Note]]}
   [{:keys [id definition-id body created author-id] :as note}]
@@ -97,3 +106,15 @@
                   [:maybe schemas.model.social/Social]]}
   [db-rows]
   (first (db->socials db-rows)))
+
+(defn db->any-socials
+  {:malli/schema [:=> [:cat [:sequential schemas.db/Row]]
+                  [:maybe [:sequential schemas.model.social/AnySocial]]]}
+  [db-rows]
+  (let [notes (db->notes db-rows)
+        examples (db->examples db-rows)
+        see-alsos (db->see-alsos db-rows)]
+    (concat
+     (seq notes)
+     (seq examples)
+     (seq see-alsos))))

src/codes/clj/docs/backend/db/postgres.clj

@@ -293,3 +293,45 @@
            sql/format)
        (execute! db)
        adapters/db->social-definition))
+
+(defn get-top-authors
+  {:malli/schema [:=> [:cat :int schemas.types/DatabaseComponent]
+                  [:maybe [:sequential schemas.model.social/Author+Interactions]]]} ; todo out schema
+  [limit db]
+  (->> (-> (sql.helpers/select
+            :author/*
+            [[:count :social/id] :interactions])
+           (sql.helpers/from [(sql.helpers/union-all
+                               (-> (sql.helpers/select
+                                    [:note/note-id :id]
+                                    [:note/author-id :author-id])
+                                   (sql.helpers/from :note))
+                               (-> (sql.helpers/select
+                                    [:example-edit/example-edit-id :id]
+                                    [:example-edit/author-id :author-id])
+                                   (sql.helpers/from :example-edit))
+                               (-> (sql.helpers/select
+                                    [:see-also/see-also-id :id]
+                                    [:see-also/author-id :author-id])
+                                   (sql.helpers/from :see-also))) :social])
+           (sql.helpers/join :author
+                             [:= :social/author-id :author/author-id])
+           (sql.helpers/group-by :author/author-id)
+           (sql.helpers/limit limit)
+           sql/format)
+       (execute! db)
+       adapters/db->author+interaction))
+
+(defn get-latest-interactions
+  {:malli/schema [:=> [:cat :int schemas.types/DatabaseComponent]
+                  [:maybe [:sequential schemas.model.social/AnySocial]]]}
+  [limit db]
+  (->> (-> (sql.helpers/union-all
+            get-note-query
+            get-example-query
+            get-see-also-query)
+           (sql.helpers/order-by :created)
+           (sql.helpers/limit limit)
+           sql/format)
+       (execute! db)
+       adapters/db->any-socials))

src/codes/clj/docs/backend/schemas/db/postgres.clj

@@ -44,3 +44,6 @@
                        :account-source
                        :avatar-url
                        :created-at]))
+
+(def Author+InteractionsRow
+  (mu/assoc AuthorRow :interactions :int))

src/codes/clj/docs/backend/schemas/model/social.clj

@@ -111,5 +111,11 @@
    [:social/examples [:sequential Example]]
    [:social/see-alsos [:sequential SeeAlso]]])
 
+(def AnySocial
+  [:or Example Note SeeAlso])
+
 (def Author+Socials
   (mu/assoc Author [:author/socials {:optional true}] [:sequential Social]))
+
+(def Author+Interactions
+  (mu/assoc Author [:author/interactions {:optional true}] :int))

test/integration/codes/clj/docs/backend/db/postgres_test.clj

@@ -4,6 +4,7 @@
             [com.stuartsierra.component :as component]
             [integration.codes.clj.docs.backend.util :as util]
             [integration.codes.clj.docs.backend.util.db.postgres :as util.db.postgres]
+            [matcher-combinators.matchers :as m]
             [parenthesin.components.config.aero :as components.config]
             [parenthesin.components.db.jdbc-hikari :as components.database]
             [parenthesin.helpers.malli :as helpers.malli]
@@ -71,7 +72,33 @@
                                                          :example/author-id)]
                                :social/see-alsos [see-also-1]}]}
 
-            (db/get-author+socials "delboni" "github" database))))
+            (db/get-author+socials "delboni" "github" database)))
+
+  (flow "check latest top authors in db"
+    (match? (m/in-any-order
+             [#:author{:author-id uuid?
+                       :login "not-delboni"
+                       :account-source "github"
+                       :avatar-url "https://my.pic.com/me.jpg"
+                       :created-at inst?
+                       :interactions 3}
+              #:author{:author-id uuid?
+                       :login "delboni"
+                       :account-source "github"
+                       :avatar-url "https://my.pic.com/me2.jpg"
+                       :created-at inst?
+                       :interactions 3}])
+            (util.db.postgres/get-top-authors 10)))
+
+  (flow "check latest social interactions in db"
+    (match? (m/in-any-order
+             [#:note{:note-id uuid?}
+              #:note{:note-id uuid?}
+              #:example{:example-id uuid?}
+              #:example{:example-id uuid?}
+              #:see-also{:see-also-id uuid?}
+              #:see-also{:see-also-id uuid?}])
+            (util.db.postgres/get-latest-interactions 10))))
 
 (defflow see-also-db-test
   {:init (util/start-system! create-and-start-components!)

test/integration/codes/clj/docs/backend/util/db/postgres.clj

@@ -108,3 +108,19 @@
     (->> database
          (db/get-by-definition definition-id)
          state-flow.api/return)))
+
+(defn get-top-authors
+  [limit]
+  (flow "get top authors with their interactions sum"
+    [database (state-flow.api/get-state :database)]
+    (->> database
+         (db/get-top-authors limit)
+         state-flow.api/return)))
+
+(defn get-latest-interactions
+  [limit]
+  (flow "get latest social interactions"
+    [database (state-flow.api/get-state :database)]
+    (->> database
+         (db/get-latest-interactions limit)
+         state-flow.api/return)))

test/unit/codes/clj/docs/backend/adapters/db/postgres_test.clj

@@ -17,6 +17,10 @@
   (properties/for-all [row (mg/generator schemas.db.postgres/AuthorRow)]
                       (m/validate schemas.model.social/Author (adapters/db->author row))))
 
+(defspec db->author+interaction-test 50
+  (properties/for-all [row (mg/generator [:sequential schemas.db.postgres/Author+InteractionsRow])]
+                      (m/validate [:sequential schemas.model.social/Author+Interactions] (adapters/db->author+interaction row))))
+
 (defspec db->note-test 50
   (properties/for-all [row (mg/generator (mu/assoc schemas.db.postgres/FullRow :type [:enum "note"]))]
                       (m/validate schemas.model.social/Note (adapters/db->note row))))
@@ -255,4 +259,78 @@
                                         :created-at #inst "2020-10-23T00:00:00.000-00:00"
                                         :definition-id "clojure.core/disj2"}])))))
 
-
+(deftest db->any-socials-test
+  (testing "should list of any social parsed in db-rows"
+    (is (match? [#:note{:note-id #uuid "d9564b50-98f8-4c04-a668-bd24c1241e34"
+                        :definition-id "clojure.core/disj"
+                        :body "my note about this function."
+                        :created-at #inst "2020-10-23T00:00:00.000-00:00"
+                        :author #:author{:author-id #uuid "387863e6-e32b-4d4b-8ec5-8cf4dab7e048"
+                                         :login "delboni"
+                                         :account-source "github"
+                                         :avatar-url "https://my.pic.com/me.jpg"
+                                         :created-at #inst "2020-10-23T00:00:00.000-00:00"}}
+                 #:note{:note-id #uuid "7aac759f-35dc-456c-9611-44589336560c"
+                        :definition-id "clojure.core/disj"
+                        :body "my second note about this function."
+                        :created-at #inst "2020-10-23T00:00:00.000-00:00"
+                        :author #:author{:author-id #uuid "387863e6-e32b-4d4b-8ec5-8cf4dab7e048"
+                                         :login "delboni"
+                                         :account-source "github"
+                                         :avatar-url "https://my.pic.com/me.jpg"
+                                         :created-at #inst "2020-10-23T00:00:00.000-00:00"}}
+                 #:example{:example-id #uuid "0f0a0fe8-7147-4d45-b212-3a32bc37d07a"
+                           :definition-id "clojure.core/disj"
+                           :body "my example about this function. edited again"
+                           :created-at #inst "2020-10-23T03:00:00.000-00:00"
+                           :author #:author{:author-id #uuid "387863e6-e32b-4d4b-8ec5-8cf4dab7e048"
+                                            :login "delboni"
+                                            :account-source "github"
+                                            :avatar-url "https://my.pic.com/me.jpg"
+                                            :created-at #inst "2020-10-23T00:00:00.000-00:00"}
+                           :editors
+                           [{:author/author-id #uuid "387863e6-e32b-4d4b-8ec5-8cf4dab7e048"
+                             :author/login "delboni"
+                             :author/account-source "github"
+                             :author/avatar-url "https://my.pic.com/me.jpg"
+                             :author/created-at #inst "2020-10-23T00:00:00.000-00:00"
+                             :editor/edited-at #inst "2020-10-23T01:00:00.000-00:00"}
+                            {:author/author-id #uuid "387863e6-e32b-4d4b-8ec5-8cf4dab7e048"
+                             :author/login "delboni"
+                             :author/account-source "github"
+                             :author/avatar-url "https://my.pic.com/me.jpg"
+                             :author/created-at #inst "2020-10-23T00:00:00.000-00:00"
+                             :editor/edited-at #inst "2020-10-23T02:00:00.000-00:00"}
+                            {:author/author-id #uuid "387863e6-e32b-4d4b-8ec5-8cf4dab7e048"
+                             :author/login "delboni"
+                             :author/account-source "github"
+                             :author/avatar-url "https://my.pic.com/me.jpg"
+                             :author/created-at #inst "2020-10-23T00:00:00.000-00:00"
+                             :editor/edited-at #inst "2020-10-23T03:00:00.000-00:00"}]}
+                 #:example{:example-id #uuid "c9df4a18-ec91-4d3f-9cb2-d65d48db88eb"
+                           :definition-id "clojure.core/disj"
+                           :body "another example about this function."
+                           :created-at #inst "2020-10-23T00:00:00.000-00:00"
+                           :author #:author{:author-id #uuid "387863e6-e32b-4d4b-8ec5-8cf4dab7e048"
+                                            :login "delboni"
+                                            :account-source "github"
+                                            :avatar-url "https://my.pic.com/me.jpg"
+                                            :created-at #inst "2020-10-23T00:00:00.000-00:00"}
+                           :editors
+                           [{:author/author-id #uuid "387863e6-e32b-4d4b-8ec5-8cf4dab7e048"
+                             :author/login "delboni"
+                             :author/account-source "github"
+                             :author/avatar-url "https://my.pic.com/me.jpg"
+                             :author/created-at #inst "2020-10-23T00:00:00.000-00:00"
+                             :editor/edited-at #inst "2020-10-23T00:00:00.000-00:00"}]}
+                 #:see-also{:see-also-id #uuid "b8a824b9-6a3a-4a10-a318-58313637ecb6"
+                            :definition-id "clojure.core/disj"
+                            :definition-id-to "clojure.core/dissoc"
+                            :created-at #inst "2020-10-23T00:00:00.000-00:00"
+                            :author #:author{:author-id #uuid "387863e6-e32b-4d4b-8ec5-8cf4dab7e048"
+                                             :login "delboni"
+                                             :account-source "github"
+                                             :avatar-url "https://my.pic.com/me.jpg"
+                                             :created-at
+                                             #inst "2020-10-23T00:00:00.000-00:00"}}]
+                (adapters/db->any-socials db-rows)))))