feat(social): adds wireout model/adapter/controller/tests

Author: rafaeldelboni

src/codes/clj/docs/backend/adapters/social.clj

@@ -33,6 +33,16 @@
    :avatar-url avatar-url
    :created-at created-at})
 
+(defn author-interaction->model->wire
+  {:malli/schema [:=> [:cat [:sequential schemas.model.social/Author+Interactions]]
+                  [:sequential schemas.wire.out.social/Author+Interactions]]}
+  [author+interactions]
+  (->> author+interactions
+       (map (fn [{:author/keys [interactions] :as author}]
+              (assoc (author->model->wire author)
+                     :interactions interactions)))
+       (sort-by :interactions #(compare %2 %1))))
+
 (defn editor->model->wire
   {:malli/schema [:=> [:cat schemas.model.social/Editor] schemas.wire.social/Editor]}
   [{:editor/keys [edited-at] :as author}]
@@ -129,3 +139,22 @@
   (enc/assoc-some
    (author->model->wire author)
    :socials (map social->model->wire socials)))
+
+(defn any-social->model->wire
+  {:malli/schema [:=> [:cat [:sequential schemas.model.social/AnySocial]]
+                  [:maybe [:sequential schemas.wire.out.social/AnySocial]]]}
+  [any-socials]
+  (let [notes (->> any-socials
+                   (filter #(:note/note-id %))
+                   (map note->model->wire))
+        examples (->> any-socials
+                      (filter #(:example/example-id %))
+                      (map example->model->wire))
+        see-alsos (->> any-socials
+                       (filter #(:see-also/see-also-id %))
+                       (map see-also->model->wire))]
+    (->> (concat
+          (seq notes)
+          (seq examples)
+          (seq see-alsos))
+         (sort-by :created-at #(compare %2 %1)))))

src/codes/clj/docs/backend/controllers/social.clj

@@ -86,3 +86,15 @@
                   [:maybe schemas.model.social/Social]]}
   [definition-id {:keys [database]}]
   (db.postgres/get-by-definition definition-id database))
+
+(defn get-top-authors
+  {:malli/schema [:=> [:cat :int schemas.types/Components]
+                  [:maybe [:sequential schemas.model.social/Author+Interactions]]]}
+  [limit {:keys [database]}]
+  (db.postgres/get-top-authors limit database))
+
+(defn get-latest-interactions
+  {:malli/schema [:=> [:cat :int schemas.types/Components]
+                  [:maybe [:sequential schemas.model.social/AnySocial]]]}
+  [limit {:keys [database]}]
+  (db.postgres/get-latest-interactions limit database))

src/codes/clj/docs/backend/ports/http_in/social.clj

@@ -155,3 +155,19 @@
             :notes []
             :examples []
             :see-alsos []})})
+
+(defn get-top-authors
+  [{{{:keys [limit]} :query} :parameters
+    components :components}]
+  {:status 200
+   :body (-> (or limit 10)
+             (controllers.social/get-top-authors components)
+             adapters.social/author-interaction->model->wire)})
+
+(defn get-latest-interactions
+  [{{{:keys [limit]} :query} :parameters
+    components :components}]
+  {:status 200
+   :body (-> (or limit 10)
+             (controllers.social/get-latest-interactions components)
+             adapters.social/any-social->model->wire)})

src/codes/clj/docs/backend/routes.clj

@@ -169,7 +169,24 @@
               :responses {200 {:body schemas.wire.out.social/Social}
                           404 {:body :string}
                           500 {:body :string}}
-              :handler ports.http-in.social/get-by-definition}}]]]
+              :handler ports.http-in.social/get-by-definition}}]]
+
+     ["/query"
+      ["/top-authors"
+       {:get {:summary "get top contributing author list"
+              :parameters {:query [:map [:limit {:optional true} :int]]}
+              :responses {200 {:body [:sequential schemas.wire.out.social/Author+Interactions]}
+                          404 {:body :string}
+                          500 {:body :string}}
+              :handler ports.http-in.social/get-top-authors}}]
+
+      ["/latest-interactions"
+       {:get {:summary "get latest social interactions list"
+              :parameters {:query [:map [:limit {:optional true} :int]]}
+              :responses {200 {:body [:sequential schemas.wire.out.social/AnySocial]}
+                          404 {:body :string}
+                          500 {:body :string}}
+              :handler ports.http-in.social/get-latest-interactions}}]]]
 
     ["/document"
      {:swagger {:tags ["document"]}}

src/codes/clj/docs/backend/schemas/model/social.clj

@@ -118,4 +118,4 @@
   (mu/assoc Author [:author/socials {:optional true}] [:sequential Social]))
 
 (def Author+Interactions
-  (mu/assoc Author [:author/interactions {:optional true}] :int))
+  (mu/assoc Author :author/interactions :int))

src/codes/clj/docs/backend/schemas/wire/out/social.clj

@@ -33,5 +33,11 @@
    [:examples [:sequential Example]]
    [:see-alsos [:sequential SeeAlso]]])
 
+(def AnySocial
+  [:or Example Note SeeAlso])
+
 (def Author+Socials
   (mu/assoc Author [:socials {:optional true}] [:sequential Social]))
+
+(def Author+Interactions
+  (mu/assoc Author :interactions :int))

test/integration/codes/clj/docs/backend/social_test.clj

@@ -158,6 +158,31 @@
                 (state-flow.server/request! {:method :get
                                              :uri    "/api/social/author/delboni/github"})))
 
+      (flow "should return top authors"
+        (match? {:status 200
+                 :body [{:author-id string?
+                         :login "delboni"
+                         :account-source "github"
+                         :avatar-url "https://my.pic/me.jpg"
+                         :created-at string?
+                         :interactions 1}]}
+                (state-flow.server/request! {:method :get
+                                             :uri    "/api/social/query/top-authors"})))
+
+      (flow "should return latest interactions"
+        (match? {:status 200
+                 :body [{:note-id string?
+                         :definition-id "clojure.core/disj"
+                         :body "my edited note about this function."
+                         :created-at string?
+                         :author {:author-id string?
+                                  :login "delboni"
+                                  :account-source "github"
+                                  :avatar-url "https://my.pic/me.jpg"
+                                  :created-at string?}}]}
+                (state-flow.server/request! {:method :get
+                                             :uri    "/api/social/query/latest-interactions"})))
+
       (flow "should not be able to delete if not allowed"
         (match? {:status 403
                  :body "You not allowed to delete this note."}
@@ -246,6 +271,26 @@
                   (state-flow.server/request! {:method :get
                                                :uri    "/api/social/author/delboni/github"})))
 
+        (flow "should return top authors"
+          (match? {:status 200
+                   :body [{:author-id string?
+                           :login "delboni"
+                           :account-source "github"
+                           :avatar-url "https://my.pic/me.jpg"
+                           :created-at string?
+                           :interactions 1}]}
+                  (state-flow.server/request! {:method :get
+                                               :uri    "/api/social/query/top-authors"})))
+
+        (flow "should return latest interactions"
+          (match? {:status 200
+                   :body [{:see-also-id see-also-id
+                           :definition-id "clojure.core/disj"
+                           :definition-id-to "clojure.core/dissoc"
+                           :created-at string?}]}
+                  (state-flow.server/request! {:method :get
+                                               :uri    "/api/social/query/latest-interactions"})))
+
         (flow "should not be able to delete if not allowed"
           (match? {:status 403
                    :body "You not allowed to delete this see also."}
@@ -386,6 +431,38 @@
                   (state-flow.server/request! {:method :get
                                                :uri    "/api/social/author/delboni/github"})))
 
+        (flow "should return top authors"
+          (match? {:status 200
+                   :body [{:author-id string?
+                           :login "delboni"
+                           :account-source "github"
+                           :avatar-url "https://my.pic/me.jpg"
+                           :created-at string?
+                           :interactions 2}]}
+                  (state-flow.server/request! {:method :get
+                                               :uri    "/api/social/query/top-authors"})))
+
+        (flow "should return latest interactions"
+          (match? {:status 200
+                   :body [{:example-id example-id
+                           :definition-id "clojure.core/disj"
+                           :body "my edited example about this function."
+                           :created-at string?
+                           :editors [{:author-id string?
+                                      :login "delboni"
+                                      :account-source "github"
+                                      :avatar-url "https://my.pic/me.jpg"
+                                      :created-at string?
+                                      :edited-at string?}
+                                     {:author-id string?
+                                      :login "delboni"
+                                      :account-source "github"
+                                      :avatar-url "https://my.pic/me.jpg"
+                                      :created-at string?
+                                      :edited-at string?}]}]}
+                  (state-flow.server/request! {:method :get
+                                               :uri    "/api/social/query/latest-interactions"})))
+
         (flow "delete example revision part 1"
           (state-flow.server/request! {:method :delete
                                        :headers {"authorization" (str "Bearer " token)}

test/unit/codes/clj/docs/backend/adapters/social_test.clj

@@ -28,6 +28,11 @@
                       (m/validate schemas.wire.social/Author
                                   (adapters.social/author->model->wire author))))
 
+(defspec author-interaction->model->wire-test 50
+  (properties/for-all [author+interaction (mg/generator schemas.model.social/Author+Interactions)]
+                      (m/validate [:sequential schemas.wire.out.social/Author+Interactions]
+                                  (adapters.social/author-interaction->model->wire [author+interaction]))))
+
 (defspec editor->model->wire-test 50
   (properties/for-all [editor (mg/generator schemas.model.social/Editor)]
                       (m/validate schemas.wire.social/Editor
@@ -87,3 +92,8 @@
   (properties/for-all [author+socials (mg/generator schemas.model.social/Author+Socials)]
                       (m/validate schemas.wire.out.social/Author+Socials
                                   (adapters.social/author+socials->model->wire author+socials))))
+
+(defspec any-social->model->wire-test 50
+  (properties/for-all [any-social (mg/generator schemas.model.social/AnySocial)]
+                      (m/validate [:sequential schemas.wire.out.social/AnySocial]
+                                  (adapters.social/any-social->model->wire [any-social]))))